[devote]

К сожалению, найти в сети живой пример отправки файла через сокеты не получилось =(

Зачем тут сокеты? Отправить данные из флеша и без сокетов можно. Таким же образом что отправка файлов, только отправлять не файлы а накопленный буфер.

package com.net {

	/*
	* author: devote
	*/
	
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.net.URLVariables;
	import flash.net.URLRequestMethod;
	import flash.net.URLRequestHeader;
	import flash.utils.ByteArray;
	import flash.events.ProgressEvent;
	
	public class MultipartSender extends URLLoader {
		
		private var multiPartFields: ByteArray;
		private var _params: * ;
		private var _variables: URLVariables;
		
		public function MultipartSender(): void {
			super();
			multiPartFields = new ByteArray();
			_variables = new URLVariables();
		}
		
		public function addMultipartField( sName: String, sValue: * ): void {
			_variables[ sName ] = sValue;
		}
		
		public function addMultipartFile( sName: String, sFileName: String, data: ByteArray ): void {
			_variables[ sName + "[filename]" ] = sFileName;
			_variables[ sName + "[filesize]" ] = data.length;
			multiPartFields.writeBytes( data );
		}
		
		public function Send( url: String ): Boolean {
			var AcceptHeader: URLRequestHeader = new URLRequestHeader( "Accept", "*/*" );
			
			var request: URLRequest = new URLRequest( url );
			request.requestHeaders.push( AcceptHeader );
			
			request.method = URLRequestMethod.POST;
			//trace(_variables.toString());
			
			if ( multiPartFields.length > 0 ) {
				request.url = url + "?" + _variables.toString();
				request.data = multiPartFields;
			} else {
				request.data = _variables;
			}
			
			//addEventListener(ProgressEvent.PROGRESS, function(e: ProgressEvent): void {
			//	e.
			//});

			var result: Boolean = false;
			
			try {
				this.load( request );
				result = true;
			} catch( error: Error ) {
				trace( "Unable to load requested document." );
			}
			
			multiPartFields.clear();
			_variables = new URLVariables();
			return result;
		}
		
		public function set params( value: * ): void {
			_params = value;
		}
		
		public function get params(): * {
			return _params;
		}
	}
}

Использовать примерно так:

ms = new MultipartSender();

ms.addEventListener(Event.COMPLETE, function(e: Event): void {
    trace("complete");
    trace(e.currentTarget.data.toString());
});

ms.addEventListener(ProgressEvent.PROGRESS, function(e: ProgressEvent): void {
    trace(e.bytesLoaded, e.bytesTotal);
});
					
ms.addEventListener(IOErrorEvent.NETWORK_ERROR, function(e: IOErrorEvent): void {
    trace(e.currentTarget.data);
    trace("error");
});
					
ms.addMultipartFile( "testnamefield", "file.jpg", Buffer );
ms.addMultipartField( "test", "val" );
ms.Send("http://somesite.com/test.php");